|
|
|
|
 |
 |
 Home > Board > Software |
|
| 글 보 기 |
|
| 글쓴이 |
jinnie4u (2005-04-25 10:17:57) |
|
| 제목 |
MTS310보드에서 Accelerometer X, Y 값 동시에 읽어 오기 |
조회 : 12700 |
|
MTS310 에는 빛(Light), 가속도(Accelerometer), 소리(Microphone), 자기(Magnetometer) 등의 센서가 있습니다.
이중에 가속도 센서를 이용해, Accelerometer의 X, Y 데이터를 Base 로 전송하고
이를 TOS의 자바 프로그램인 오실로스코프를 이용, 그래프로 출력하도록 하였습니다.
원본 프로그램은 xbow 에서 제공된 TestSensor 라는 프로그램입니다.
TestSensor는 MTS300(또는 310)의 모든 센서로 부터의 데이터를 UART, RF Communication 을 이용해 전송해주는 프로그램입니다.
이 프로그램을 Accel 센서만 사용하도록, 오실로스코프에서 확인할 수 있는 형태로 패킷을 전송하도록 수정하였습니다.
X와 Y, 두가지 데이터별로 별도로 ADC를 호출하는데 사용된 함수는
AccelX.getData(), AccelY.getData()로 AccelX와 AccelY가 각각
X축과 Y축의 데이터를 읽어들입니다.
전송하는 데이터 타입은 OscilloscpeRF에 있는 struct OscopeMsg
타입의 구조체를 사용하였습니다.
하나의 노드에서 X,Y 두개의 값이 전송되기 때문에 이를 구분해주기 위해
채널번호를 서로 다르게 해주었습니다.
X용 : pack->channel = 7;
Y용 : pack->channel = 9;
두개의 데이터를 담은 두 패킷을 연속적으로 전송하고자 할 경우
네트워크단에서 버퍼가 전송중에 바뀌거나 하는 문제가 발생하는지
정상적으로 전송되지 않습니다. TinyOS는 네트워크전송에도 이벤트를
사용하며 이는 nonblocking기법 처럼 동작하게 됩니다.
이런 문제를 해결하기 위해 하나의 패킷을 모두 전송하였다는 것을
확인한 후에 다른 패킷을 전송하도록 하였습니다.
~~~ 동작방식 ~~~
1. 초기화
- ADC
- Accelerometer
- Timer
- Leds
2. Timer fired
- ADC에 Accelerometer X 값 읽기 요청
( call AccelX.getData() )
3. ADC에 Accelerometer X 값 준비됨 event발생
- async event result_t AccelX.dataReady(uint16_t data) 함수 실행됨
- struct OscopeMsg 구조체에 데이터 저장
4. X용 Buffer가 다 찼는지 여부 판별
- 버퍼에 여유가 있는 경우
- Y값 읽기 요청
(call AccelY.getData())
- 버퍼가 다 찬 경우
- 데이터 전송
(call SendMsg.send(TOS_BCAST_ADDR, sizeof(struct OscopeMsg),&Buffer_X);
5. ADC에 Accelerometer Y 값 준비됨 event발생
- X값 읽기후 ( Buffer크기 - 1 )번 만큼 호출됨
- 마지막 것은 X데이터 전송후에 호출
6. 패킷 전송 이벤트 발생
(event result_t SendMsg.sendDone(TOS_MsgPtr sent, result_t success) )
- 전송된 패킷이 X값을 저장한 것일 경우
- Y값 읽기 요청
(call AccelY.getData())
----------------------------------------------------------------------------
includes sensorboard;
includes Msg;
includes OscopeMsg; // Oscilloscope 에서 사용되는 메시지타입 포함
module TestSensorM {
provides { interface StdControl; }
uses {
interface StdControl as CommControl;
interface SendMsg as SendMsg;
interface ReceiveMsg as ReceiveMsg;
// Accel
interface StdControl as AccelControl;
interface ADC as AccelX;
interface ADC as AccelY;
interface ADCControl;
interface Timer;
interface Leds;
}
}
implementation {
TOS_Msg Buffer_X;
TOS_Msg Buffer_Y;
norace uint8_t packetReadingNumber1, packetReadingNumber2; // 하나의 패킷에 추가된 데이터의 카운트
norace uint16_t readingNumber1, readingNumber2;
norace uint8_t msg_sent1, msg_sent2;
// 컴포넌트, ADCControl, Leds 초기화
command result_t StdControl.init()
{
// 변수 초기화
readingNumber1 = 0;
readingNumber2 = 0;
packetReadingNumber1 = 0;
packetReadingNumber2 = 0;
msg_sent1 = 0;
msg_sent2 = 0;
// 컴포넌트 초기화
call ADCControl.init();
call Leds.init();
call AccelControl.init();
return SUCCESS;
}
// 컴포넌트 시작 및 타이머 시작
command result_t StdControl.start()
{
call AccelControl.start();
call Timer.start(TIMER_REPEAT, 100); // 0.1 sec
return SUCCESS;
}
// 컴포넌트 정지
command result_t StdControl.stop() {
call AccelControl.stop();
return SUCCESS;
}
// StdControl.start()의 Timer.start()에서 설정한 시간이 expire 될 때 실행
// X data Sampling
event result_t Timer.fired()
{
// call Leds.yellowToggle(); // 주석 제거시 0.1초마다 Yellow LED 토글
if( msg_sent1==0 && msg_sent2 == 0) {
call AccelX.getData();
}
return SUCCESS;
}
// X 데이터 샘플링 완료시 실행
// X 데이터를 oscilloscope 패킷에 실어 RF 전송
async event result_t AccelX.dataReady(uint16_t data)
{
struct OscopeMsg *pack; // 오실로스코프 타입의 패킷
// 전송할 데이터가 저장된 공간을 오실로스코프타입에 포인터로 매핑
pack = (struct OscopeMsg *)Buffer_X.data;
// 읽어온 데이터를 패킷에 저장, 패킷에 저장된 데이터카운트 증가
pack->data[packetReadingNumber1++] = data;
readingNumber1++;
// 패킷에 저장된 데이터수가 버퍼의 크기와 같을 경우 패킷 전송
if (packetReadingNumber1 >= BUFFER_SIZE ) {
msg_sent1 = 1;
// 패킷에 저장된 데이터수 카운트 초기화
packetReadingNumber1 = 0;
// 현재까지 읽어온 총 데이터수 저장
pack->lastSampleNumber = readingNumber1;
// 데이터를 읽어온 채널번호 저장
pack->channel = 7;
// 현재 mote의 아이디 저장
pack->sourceMoteID = TOS_LOCAL_ADDRESS;
call Leds.redToggle(); // Red LED 토글
// OscopeMsg형태로 패킷 전송
call SendMsg.send(TOS_BCAST_ADDR, sizeof(struct OscopeMsg),&Buffer_X);
}
else call AccelY.getData(); // Y 데이터 샘플링
return SUCCESS;
}
// Y 데이터 샘플링 완료시 실행
// Y 데이터를 oscilloscope 패킷에 실어 RF를 이용해 전송
async event result_t AccelY.dataReady(uint16_t data)
{
struct OscopeMsg *pack; // 오실로스코프 타입의 패킷
pack = (struct OscopeMsg *)Buffer_Y.data;
pack->data[packetReadingNumber2++] = data;
readingNumber2++;
if (packetReadingNumber2 >= BUFFER_SIZE) {
packetReadingNumber2 = 0;
pack->lastSampleNumber = readingNumber2;
pack->channel = 9;
// 현재 모트 아이디에 2를 더해 Y 값에 대한 ID 설정
pack->sourceMoteID = TOS_LOCAL_ADDRESS + 2;
call Leds.greenToggle();// Green LED 토글
call SendMsg.send(TOS_BCAST_ADDR, sizeof(struct OscopeMsg),&Buffer_Y);
}
return SUCCESS;
}
// dataReady 에서 SendMsg.send() 호출 후 실행
event result_t SendMsg.sendDone(TOS_MsgPtr sent, result_t success)
{
// X 데이터 전송 후 AccelY.getData() 실행
if( sent == &Buffer_X ) {
msg_sent1 = 0;
call Leds.redOff();
call AccelY.getData();
}
// Y 데이터 전송 후 Green LED Off 후 readingNumber 셋
if( sent == &Buffer_Y ) {
msg_sent2=0;
call Leds.greenOff();
readingNumber1=readingNumber2;
}
return SUCCESS;
}
// 오실로스코프로부터 메시지 수신시
// 현재 읽어들인 버퍼 인덱스 초기화
// X, Y readingNumber 동기화
event TOS_MsgPtr ReceiveMsg.receive(TOS_MsgPtr data)
{
packetReadingNumber1 = 0;
packetReadingNumber2 = 0;
readingNumber1 = readingNumber2;
return data;
}
}
By jinnie4u ( jinnie4u@hotmail.com, jhlee@snslab.kangwon.ac.kr ) |
|
|
|
|
|
|
|
|
|
|
|
|
